圆月山庄资源网

Windows批量搜索并复制/剪切文件的批处理程序实例
脚本专栏 2024/11/1 佚名
3 2
圆月山庄资源网 Design By www.vgjia.com

搜索包含关键字的文件名是最常用的功能之一，比如按人名搜索mp3、按内容搜索图纸等等，当需要搜索成百上千个关键词时，会消耗大量的人力和时间，这时就需要批量搜索功能。本文介绍一个我自己编写的、用于批量搜索文件的批处理程序。

搜索包含关键字的文件名是最常用的功能之一，比如按人名搜索mp3、按内容搜索图纸等等，当需要搜索成百上千个关键词时，会消耗大量的人力和时间，这时就需要批量搜索功能。

传统方法

Windows XP自带了批量搜索的功能，在按（Win+F）弹出的搜索框中，填入若干关键词，用逗号隔开，这样搜出的结果是包含至少一个关键词的文件。但是这种搜索方法有关键字数量的限制，而且要把一堆关键词用逗号隔开也是需要点工夫的，当然你可以用Excel处理，但总归比较麻烦。下面介绍一个我自己编写的批处理程序。

任务描述

所谓批量搜索是在一批文件名里寻找多个关键词，比如

关键词列表：AA,BB,CC

目标文件名：AA1,BB2,DD3,BBC1,EE2,Abb

批量搜索得到的结果有：AA1，BB2，BBC1，Abb

因为Windows系统对文件名的大小写只记录，不区分，所以Abb也能被搜出来。

解决方法

利用批处理程序中强大的for命令，可以很好的完成批量的搜索。结合其他批处理命令，还能将搜出来的文件复制或者剪切到目的路径下面。

首先把关键字保存在名叫“list.txt”的文本文件里，每个关键字占一行。注意不能有空格、空行、空回车。例如：

AA

BB

CC

然后把下面的代码保存成以 *.bat 为扩展名的批处理文件。代码如下：

::Batch search & copy/move, Mar 21,2009
::..

@echo off
color 3E
echo 本程序复制/剪切当前目录下含有特定关键字的特定类型文件
echo 注意：覆盖不提示，请小心操作
echo 注意：关键字列表不要有空格、空行、空回车
echo.
if not exist list.txt (echo.
echo 请先将关键字列表保存为list.txt...
pause > NUL
exit
)
echo.
echo 选择要进行的操作：
set /p opt=复制(c) or 剪切(x):
if %opt% NEQ c if %opt% NEQ x (
echo 没有选项，byebye!
pause >NUL
exit
)
set /p ext=指定文件扩展名（不含"."，比如pdf，不指定请输入*）:
set /p url=目标文件夹路径（不可在当前目录内）：
if not exist %url% md %url%
if %opt%==c set task=复制
if %opt%==x set task=剪切
echo 按任意键开始%task%....
pause > NUL

set count=0
for /f "tokens=*" %%i in (list.txt) do (
 for /r %%j in (*%%i*.%ext%) do (
echo 正在%task% %%j 到 %url%
if %opt%==c (copy "%%j" %url% >NUL)
if %opt%==x (move "%%j" %url% >NUL)
set /a count+=1
 )
)
echo.
echo 任务完成！共%task%了%count%个文件
echo.
echo by www.lfhacks.com
echo ..
pause >NUL
exit

把批处理文件和list.txt都放在要搜索的文件目录下，运行批处理文件，按提示操作即可，注意大小写敏感。由于for命令先天的限制，有两点需要注意：

  1. 被搜索文件不能放在根目录下，需要放在子目录内
  2. 复制或者剪切的目的地最好在另外一个驱动器内，不然可能会造成死循环。

对上述代码稍作修改，可以得到其他定制的功能，比如，下面的代码就是建立以关键字命名的独立目录，作为复制/剪切的目的地。这个代码可以用来将文件按某个字段分配到多个文件夹里：

::Batch search & copy/move, Mar 21,2009
::..

@echo off
color 3E
echo 本程序复制/剪切当前目录下含有特定关键字的特定类型文件
echo 注意：覆盖不提示，请小心操作
echo 注意：关键字列表不要有空格、空行、空回车
echo.
if not exist list.txt (echo.
echo 请先将关键字列表保存为list.txt...
pause > NUL
exit
)
echo.
echo 选择要进行的操作：
set /p opt=复制(c) or 剪切(x):
if %opt% NEQ c if %opt% NEQ x (
echo 没有选项，byebye!
pause >NUL
exit
)
set /p ext=指定文件扩展名（不含"."，比如pdf，不指定请输入*）:
set /p url=目标文件夹路径（不可在当前目录内，末尾不要带斜杠\）：
if not exist %url% md %url%
if %opt%==c set task=复制
if %opt%==x set task=剪切
echo 按任意键开始%task%....
pause > NUL

set count=0
for /f "tokens=*" %%i in (list.txt) do (
 md %url%\%%i
 for /r %%j in (*%%i*.%ext%) do (
echo 正在%task% %%j 到 %url%\%%i
if %opt%==c (copy /Y "%%j" "%url%\%%i" >NUL)
if %opt%==x (move /Y "%%j" "%url%\%%i" >NUL)
set /a count+=1
 )
)
echo.
echo 任务完成！共%task%了%count%个文件
echo.
echo by www.lfhacks.com
echo ..
pause >NUL
exit

在批量搜索并转移文件后，往往需要和原有的关键字比对，知道搜索到了多少文件。这就需要一个工具，能够批量检测一批关键字是否存在于一堆文件里。请参考另一篇文章： 批量检测文件（夹）是否存在的批处理程序

标签：
Windows批量搜索批处理程序,Windows批量复制批处理程序,Windows批量剪切文件批处理程序
圆月山庄资源网 Design By www.vgjia.com
广告合作：本站广告合作请联系QQ：858582 申请时备注：广告合作（否则不回）
免责声明：本站文章均来自网站采集或用户投稿，网站不提供任何软件下载或自行开发的软件！ 如有用户或公司发现本站内容信息存在侵权行为，请邮件告知！ 858582#qq.com
圆月山庄资源网 Design By www.vgjia.com
www.vgjia.com 圆月山庄资源网
139,976互联网资源
144,792高清电影
21,817无损音乐
631,128技术资源

更新日志

友情链接

杰晶网络 DDR爱好者之家 桃源资源网 杰网资源 富贵资源网 南强小屋 铁雪资源网 幽灵资源网 万梅资源网 狼山资源网 白云岛资源网 昆仑资源网 相思资源网 明霞山资源网 内蒙古资源网 黑松山资源网 茶园资源网 饿虎岗资源网 大旗谷资源网 常春岛资源网 岱庙资源网 兴国资源网 快活林资源网 蝙蝠岛资源网 帝王谷资源网 白云城资源网 伏龙阁资源网 清风细雨楼 天枫庄资源网 圆月山庄资源网 无争山庄资源网 神水资源网 移花宫资源网 神剑山庄资源网 无为清净楼资源网 金钱帮资源网 丐帮资源网 华山资源网 极乐门资源网 小李飞刀资源网 凤求凰客栈 风云阁资源网 金狮镖局 鸳鸯亭资源网 千金楼资源网 更多链接